
;This pulse program has been created by Patrick Giraudeau and Serge Akoka, CEISAM, University of Nantes, France
;The authors are not responsible for the results obtained with this pulse sequence, and decline responsibility for any damage resulting from the use of this program
;Please refer to the protocol provided with this pulse sequence for correctly adjusting acquisition and processing parameters
;Please do not delete this header from the pulse program.

;iufdqs
;avance-version (02/05/31)
;1D sequence
;modified by laetitia rouger 21/04/2017
;UFDQS with constant-time phase encoding

;$CLASS=HighRes
;$DIM=2D
;$TYPE=
;$SUBTYPE=
;$COMMENT=



#include <Avance.incl>
#include <Grad.incl>
#include <De.incl>
#include <Delay.incl>


"d0=3u"
"d2=3u"
"d11=30m"
"d12=20u"
"d13=4u"
"p15=(td*dw/(2*l3))-d6" 
"p24=p15"
"p2=2*p1"
"d4=1s/(4*cnst1)"
"in2=2*(p15+d6)/td1"



1 ze
	d11 ;pl14:f2  
	20u st0


  30m zd

;Dummy Scan loop
21 30m
	4u ;cw:f2 ph29
  d1 
	4u ;do:f2
  100u UNBLKGRAD
  20u pl1:f1

;excitation

  p1 ph1
	d4
	p2 ph2
	d4
	p1 ph2

;spatial encoding
  10u gron0
  p11:sp1:f1 ph1
  10u groff
  p20:gp20
  10u gron1
  p11:sp1:f1 ph2
  10u groff
  p21:gp21

;pre-mixing gradient
  10u
	p24:gp24
  10u

;mixing
  p23:gp23
  10u
  5u pl1:f1
  p10 ph2
  10u
  p26:gp26
  
;post-mixing gradient
  10u
  p24:gp25
  10u

31 p15:gp15
  d6 
  p15:gp16
  d6
  lo to 31 times l3
	p27:gp27
  100u BLKGRAD
	lo to 21 times l4

;end of Dummy Scan loop


2 30m
	4u ;cw:f2 ph29
  d1 
	4u ;do:f2
  100u UNBLKGRAD
  20u pl1:f1

;excitation

  p1 ph1
	d4
	p2 ph2
	d4
	p1 ph2

;spatial encoding
  10u gron0
  p11:sp1:f1 ph1
  10u groff
  p20:gp20
  10u gron1
  p11:sp1:f1 ph2
  10u groff
  p21:gp21

;pre-mixing gradient
  10u
	p24:gp24
  10u

;mixing
  p23:gp23
  10u
  5u pl1:f1
  p10 ph2
  10u
  p26:gp26
  
;post-mixing gradient
  10u
  p24:gp25
  10u

	d2

;acquisition
  ACQ_START(ph30,ph31)
  1u DWELL_GEN:f1
3 p15:gp15
  d6 
  p15:gp16
  d6
  lo to 3 times l3
	100u BLKGRAD
  rcyc=2
  100u UNBLKGRAD
	;purge gradient
  p27:gp27
  100u BLKGRAD
  30m mc #0 to 2 F1QF(id2)
  d17
exit

ph1=0 1
ph2=0
ph3=0
ph29=0
ph30=0
ph31=0 2


;pl1 : f1 channel - power level for pulse (default)
;sp1: shaped pulse power level for selective detection
;p1 : f1 channel - 90 degree high power pulse
;p23 and p26: coherence-selection gradients for mixing(p23=p26)
;p20 and p21: coherence-selection gradients for spatial encoding(p20=p21)
;spnam1 : shaped pulse for selective detection
;d1 : relaxation delay; 1-5 * T1
;d20 + d6 : acquisition gradient duration
;d24 : pre-mixing gradient duration
;d25 : post-mixing gradient duration
;d17 : delay after experiment (not necessary)
;GPZ0 : strength for excitation gradient [0-100]
;GPZ1 : strength for reversed excitation gradient GPZ1 = -GPZ0
;GPZ2 : strength for acquisition gradient [0-100]
;GPZ3 : strength for reversed acquisition gradient GPZ3 = -GPZ2
;GPZ20 and GPZ21: coherence-selection gradients for spatial encoding (GPZ20=GPZ21)
;GPZ23 and GPZ26: coherence-selection gradients for mixing (GPZ26=-GPZ23)
;GPZ24 and GPZ25: pre- and post-mixing gradients
;GPNAM20=GPNAM21=GPNAM23=GPNAM26=SINE.100
;NS: 1 (or more if necessary)
;l3=number of loops for acquisition
;IMPORTANT: set d20 + d6 = DW x TD(F2)/(2xL3)

;$Id: zgselgs,v 1.1 2006/05/26 12:17:01 ber Exp $
